Cómo crear transiciones entre fotogramas en Flash

Por: Zguillez

19 de Enero del 2010

7273 de clabLevel
Otros artículos de Zguillez

3,337 visitas

flash animacion actionscript_3

Hace unos días me preguntaron como crear transiciones entre fotogramas en Flash. Esto es una tarea bastante sencilla de implementar así que aprovecho para explicarla en forma de Tip.

Lo que se pretende conseguir es que al cambiar de fotograma, los elementos del fotograma actual desaparezcan de forma animada antes de saltar al siguiente fotograma. Como se ve en el ejemplo:

Ahora vayamos al código:

Código :

package {
   import flash.display.MovieClip;
   import flash.events.MouseEvent;
   //
   public class Main extends MovieClip {

      public var currentFrameClip:MovieClip;

      public function Main() {
         this.boton1.addEventListener(MouseEvent.CLICK,gotoFrame);
         this.boton2.addEventListener(MouseEvent.CLICK,gotoFrame);
         this.boton3.addEventListener(MouseEvent.CLICK,gotoFrame);
         this.boton4.addEventListener(MouseEvent.CLICK,gotoFrame);
         this.stop();
      }
      private function gotoFrame(e:MouseEvent):void {
         switch (e.currentTarget) {
            case boton1 :
               currentFrameClip.gotoFrame(1);
               break;
            case boton2 :
               currentFrameClip.gotoFrame(2);
               break;
            case boton3 :
               currentFrameClip.gotoFrame(3);
               break;
            case boton4 :
               currentFrameClip.gotoFrame(4);
               break;
         }
      }
   }
}

Código :

package {
   import flash.display.MovieClip;
   import flash.events.Event;
   //
   public class FrameInOut extends MovieClip {

      public var goto:uint;
      
      public function FrameInOut() {
         MovieClip(this.parent).currentFrameClip=this;
         frameIntro();
      }
      public function gotoFrame(frame:uint):void {
         if (frame!=MovieClip(this.parent).currentFrame) {
            goto=frame;
            this.gotoAndStop("on");
            this.addEventListener(Event.ENTER_FRAME,avanzaFrame);
         }
      }
      //-----------------------------------------------------
      private function frameIntro():void {
         this.gotoAndStop("out");
         this.addEventListener(Event.ENTER_FRAME,retrocedeFrame);
      }
      private function retrocedeFrame(e:Event):void {
         if (this.currentLabel=="on") {
            this.removeEventListener(Event.ENTER_FRAME,retrocedeFrame);
         } else {
            this.prevFrame();
         }
      }
      private function avanzaFrame(e:Event):void {
         if (this.currentLabel=="out") {
            this.removeEventListener(Event.ENTER_FRAME,avanzaFrame);
            MovieClip(this.parent).gotoAndStop(goto);
         } else {
            this.nextFrame();
         }
      }
   }
}

UPDATE:

Código :

package
{
   import flash.display.MovieClip;
   import flash.events.Event;
   //
   public class FrameInOut extends MovieClip
   {
      public var goto:uint;
      //
      public function FrameInOut()
      {
         MovieClip(this.parent).currentFrameClip = this;
         this.gotoAndPlay("out");
      }
      public function gotoFrame(frame:uint):void
      {
         if(frame != MovieClip(this.parent).currentFrame)
         {
            goto = frame;
            this.addFrameScript(19, foo);
            this.gotoAndPlay("anim");
         }
      }
      private function foo():void
      {
         this.addFrameScript(19, null);
         MovieClip(this.parent).gotoAndStop(goto);
      }
   }
}

También te interesa

• Videotutorial sobre cómo animar un reno en Flash
• Videotutorial sobre cómo dibujar un árbol navideño en Flash
• Videotutorial Flash: animación de etiqueta

flash animacion actionscript_3

@Freddie no podía tener más la razón (esta vez) gracias por el tip
Por: hCanté

Muchas muchísimas gracias, y... (todo lo demás que te he dicho en los demás medios)

Saludos
Por: Distriker

Distriker :

Muchas muchísimas gracias, y... (todo lo demás que te he dicho en los demás medios)

Saludos

De nada, espero que haya servido
Por: Zguillez

currodelatajadera-blog :

lo que no entiendo es como hace uso de las clases desde el archivo fla, si no veo el import por ningún lado.Perdonen pero soy novatisimo en as3 jejejej.

La clase Main está asignada a la pelicula desde el panel de propiedades, y la clase del MovieClip se asigna en el menu de vinculacion desde la biblioteca
Por: Zguillez

Zguillez :

currodelatajadera-blog :

lo que no entiendo es como hace uso de las clases desde el archivo fla, si no veo el import por ningún lado.Perdonen pero soy novatisimo en as3 jejejej.

La clase Main está asignada a la pelicula desde el panel de propiedades, y la clase del MovieClip se asigna en el menu de vinculacion desde la biblioteca

Muchas gracias por preguntar Curro, y a ti ZGuillez por contestarlo, era algo que también me rondaba por la cabeza.

Como diablos la clase Main y del Movie clip.

Saludos y gracias.
Por: Distriker

es correcto Z, el UPDATE es solo otra forma de hacerlo y podemos encontrar miles
Por: eldervaz

nombre_instancia_mc.on (release) {
   gotoAndStop (2) ;
}