Paleta de colores en Flash con Actionscript 2

Por: Wyrm

1 de Septiembre del 2009

1244 de clabLevel
Otros artículos de Wyrm

3,526 visitas

diseño flash actionscript

En éste sencillo(mas o menos) tutorial, vamos a realizar una paleta de colores seleccionable con BitmapData. En éste caso, usaré Flash 8, y los archivos del tutorial, serán en ese formato.

Necesitamos:

• La imagen de la paleta a usar.
  
• Un clip de película llamado en instancia, "paleta_mc"
  
• Otro clip de película llamado en instancia, "punto_mc"
  
• Y otro clip llamado en instancia "selec_mc"
  
• Un cuadro de texto dinámico, llamado en instancia, "valores_txt"

Paleta de colores seleccionable en Flash con AS2

Colocando el código

Código :

//esta función es la que comprueba el color y se lo asigna a la muestra
function comprobar_color():Void {
   import flash.display.BitmapData;
   import flash.geom.ColorTransform;
   import flash.geom.Transform;
   // creamos un objeto bipmapdata con el contenido del clip de colores 
   var bitmap_1:BitmapData = new BitmapData(paleta_mc._width, paleta_mc._height);
   bitmap_1.draw(paleta_mc);
   // 
   // desplazamos el puntero de cruz y nos aseguramos de que no se salga del picker 
   punto_mc._x = Math.round(_root._xmouse);
   punto_mc._y = Math.round(_root._ymouse);
   if (punto_mc._x>paleta_mc._width-1) {
      punto_mc._x = paleta_mc._width-1;
   }
   if (punto_mc._y>paleta_mc._height-1) {
      punto_mc._y = paleta_mc._height-1;
   }
   if (punto_mc._x<0) {
      punto_mc._x = 0;
   }
   if (punto_mc._y<0) {
      punto_mc._y = 0;
   }
      // 
      // asignmos el color elegido al rectángulo de muestra 
   var color_sample:Color = new Color(selec_mc);
   color_sample.setRGB(bitmap_1.getPixel(punto_mc._x, punto_mc._y));
   // mostramos los valores RGB en la caja de texto
   var colorSeleccionado = deEXaRGB(bitmap_1.getPixel(punto_mc._x, punto_mc._y));
   valores = "RGB ("+colorSeleccionado.red+", "+colorSeleccionado.green+", "+colorSeleccionado.blue+")";
}
// cuando presionamos el clip de colores, ocultamos el ratón,
//  y ejecutamos la función comprobar_color() ,definida anteriormente
paleta_mc.onPress = function() {
   Mouse.hide();
   comprobar_color();
   delete _root.onMouseMove;
   _root.onMouseMove = function() {
      comprobar_color();
      updateAfterEvent();
   };
};
// paramos al liberar el ratón
paleta_mc.onRelease = function() {
   delete _root.onMouseMove;
   Mouse.show();
};
paleta_mc.onReleaseOutside = paleta_mc.onRelease;
// función auxiliar para convertir de hexadecimal a RGB
function deEXaRGB(valor:Number):Object {
   var RGB = new Object();
   RGB.red = (valor >> 16) & 0xFF;
   RGB.green = (valor >> 8) & 0xFF;
   RGB.blue = valor & 0xFF;
   return RGB;
}
stop();

También te interesa

• Insertar videos de youtube en Flash
• Contenedores escalables en Actionscript 2
• Hacer un portafolio con Flash y XML

diseño flash actionscript

Muchas Gracias, , voy a ver como funciona en AS3
Por: Wyrm

riajiru-blog :

Wow... Muy simple y con excelentes resultados... Gran trabajo... Y muchas gracias

Gracias a ti ...

Luego si me da tiempo, intentaré poner un ejemplo prácticocon un mueble para que vean lo que se puede llegar ha hacer
Por: Wyrm

var color_sample:Color = new Color(selec_mc);
   color_sample.setRGB(bitmap_1.getPixel(punto_mc._x, punto_mc._y));
var color_sample2:Color = new Color(selec_mc2);
   color_sample2.setRGB(bitmap_1.getPixel(punto_mc._x, punto_mc._y));

Me parece ingenioso utilizar una imagen cualquiera para obtener de ahí los colores. Anímate a publicar una versión en AS3 antes de que te la ganenmos..! Buen tip.

Por: M@U

jejeejje no soy muy ducho en AS3....creo que mejor alguien con mas experiencia en ese terreno la haria mejor...

Aunque probare, de eso estate seguro jejeje Gracias
Por: Wyrm