Efecto de estática en televisión con ActionScript 3

Por: Carloz.Yanez + 27.04.2008

Código :

package Classes
{
   //Importamos los paquetes que necesitaremos
   
   import flash.display.*;
   import flash.utils.Timer;
   import flash.events.TimerEvent;
   
   //Nombramos la clase que será heredada de la Clase Sprite para poder utilizar el método addChild
   
   public class TvEffect extends Sprite
   {
      //Creamos las variables
      
      private var X:Number; //Almacenará la posición x de el efecto
      private var Y:Number; //Almacenará la posición y de el efecto
      
      private var bmd:BitmapData; //Contendrá los datos para crear el Bitmap, en este caso sus medidas
      private var seed:int; //Guardará el RandomSeed utilizado para el método Noise, que es el que utilizaremos para crear nuestro efecto tv
      private var bmp:Bitmap; //Nuestra instancia de Bitmap
      
      private var timer:Timer = new Timer(1); //Objeto Timer que hará cambiar el Noise para producir el efecto tv
      
      //Creamos la función que nos pedirá los datos de nuestro efecto, estos son: ancho, alto, posición x y posición y
      
      public function setEffect(w:Number, h:Number, xPos:Number, yPos:Number):void
      {
         X = xPos;
         Y = yPos;
         
         bmd = new BitmapData(w, h); //Con los datos obtenidos creamos nuestro BitmapData
      }
      
      /*Esta función se encarga del efecto, lo que hace es  aplicar el método Noise a el objeto BitmapData para generar pixeles aleatorios
      y guardarlos en la instancia de nuestro Bitmap, posicionarla y añadirla al escenario*/
      
      private function main(event:TimerEvent):void
      {
         seed = int(Math.random() * int.MAX_VALUE);
         
         bmd.noise(seed, 0, 0xFF, BitmapDataChannel.RED, true); //Es importante dejar este último valor en \"true\" para que los pixeles sean en escala de grises

         bmp = new Bitmap(bmd);
         bmp.x = X;
         bmp.y = Y;
         
         addChild(bmp);
      }
      
      //Esta funcion inicia el efecto
      
      public function init():void
      {
         timer.addEventListener(TimerEvent.TIMER, main);
         timer.start();
      }
   }
}

Código :

import Classes.TvEffect;

var tve:TvEffect = new TvEffect();

tve.setEffect(ancho, alto, x, y);
tve.init();
      
addChild(tve);

flash actionscript_3

Muy buen tip, creo que lo voy a ocupar en un proyecto que hay en puerta
Por: flashreloco

Alparecer en este caso agregar una animacion puede resultar muy bien...
Pero es buen tip, sin duda a alguien le servira... Lastima que come procesador...

Por: M@U

Freddie :

Carloz, el problema es que pones un delay de 1 milisegundo al Timer, lo que asesina invariablemente el procesador. Ponle 100 milisegundos y verás como cambia el ejemplo.

Precisamente fué lo que modifiqué ayer, también se puede realizar el efecto con un for y el método setPixel, pero me parece que se ve mucho mejor de esta manera.

Aquí está el SWF con el timer ajustado a 100 milisegundos (espero que un BOFH me haga favor de actualizar el tip).

Disculpen el ejemplo, lo tuve que probar en un otros ordenadores porque en el mío no se traba.
Por: Carloz.Yanez

..y eso que es AS3 (no ActionScript 1 ó 2)
Por: [s_s]&[sos]-blog

¿Para cuando el [b]AS4/b]? con potencia de C++ Juaz!! xD

Grax Carlos, pensé que AS3 no se colgaba (con Pentium IV).
Por: [s_s]&[sos]-blog

stage.scaleMode = StageScaleMode.NO_SCALE;

noten el addChild(bmp); en el timer S
Por: EzeQL-blog

private function main(event:TimerEvent):void
{
   seed = int(Math.random() * int.MAX_VALUE);         
   bmd.noise(seed, 0, 0xFF, BitmapDataChannel.RED, true);
}

public function init():void
{       
   bmp = new Bitmap(bmd);
   bmp.x = X;
   bmp.y = Y;
   trace(bmp)
   addChild(bmp);
   timer.addEventListener(TimerEvent.TIMER, main);
   timer.start();
}

private var timer:Timer = new Timer(50);

trace(this.numChildren)

[s_s]&[sos]-blog :

..y eso que es AS3 (no ActionScript 1 ó 2)

Aun en AS2 no se cuelga tan feo si lo sabes ejecutar...
Por: M@U