Restar dos fechas en Flash con Actionscript

Por: Zah

19 de Agosto del 2006

3528 de clabLevel
Otros artículos de Zah

17,622 visitas

actionscript

Una pregunta bastante repetida en los foros es la manera de restar dos fechas, de manera más o menos rápida. Quizá podría hacerse restando días, meses y años por separado, pero sería muy largo y complejo. Sin embargo, existe el método Date.getTime(), que devuelve el número de milisegundos que han transcurrido desde una fecha (el 1 de enero de 1970, creo recordar) Ese dato no nos sirve demasiado, pero sí pueden compararse y restarse dos valores getTime y así obtenemos la diferencia entre las fechas, en milisegundos. Para convertir los milisegundos en otras unidades hay que tener en cuenta esto, que uno aprende en el colegio:
1 segundo son ----> 1000 milisegundos
1 minuto son ------> 60 segundos
1 hora son ---------> 60 minutos
1 día son -----------> 24 horas

Hay que dividir la diferencia por los números de la columna de la derecha empezando por el primero y hasta la unidad a la que quieran llegar. De modo que si quiero saber cuántas horas faltan para el 1 de Septiembre, escribo esto:

Código :

var sept:Date=new Date (2006,8,1)
//No, no me equivoco, en flash los meses están indexados a 0 por lo que Septiembre es el mes 8
difHoras= Math.floor((sept.getTime()-new Date().getTime())/(1000*60*60))
trace(difHoras);

Código :

class DateSubstract {
   private static var factors:Array = [1, 1000, 60, 60, 24];
   private static var timeValues:Array = ["miliseconds", "seconds", "minutes", "hours", "days"];
   public static function substract(dt1:Date, dt2:Date, values:Array):Object {
      //Parámetros Opcionales
      if (dt2 == undefined) {
         dt2 = new Date();
      }
      if (values == undefined) {
         values = new Array(1, 2, 3);
      }
      //El último valor del array, para saber cuánto tendremos que dividirlo     
      var lastValue:Number = values[values.length-1];
      //El objeto que devolveremos
      var resultado:Object = new Object();
      //La diferencia en milisegundos
      var dif:Number = dt1.getTime()-dt2.getTime();
      var total:Number = dif;
      //La pasamos a las unidades superiores
      for (var i:Number = 0; i<=lastValue; i++) {
         total /= factors[i];
      }
      var j:Number = values.length-1;
      for (i=factors.length-1; i>=0; i--) {
         //Si hemos pedido ese dato..
         if (values[j] == i) {
            //lo redondeamos y devolvemos el resultado redondeado
            var redondeado:Number = Math.floor(total);
            resultado[timeValues[i]] = redondeado;
            //Restamos la cantidad que ya hemos dvuelto a la que queda
            total -= redondeado;
            j--;
         }
         //De todas formas multiplicamos el resultado por el factor 
         total *= factors[i];
      }
      return resultado;
   }
}

Código :

import DateSubstract;
dt = new Date(2006, 11, 25);
obj = DateSubstract.substract(dt, new Date(), [0, 1, 2, 4]);
trace("Quedan "+obj.days+" días, "+obj.minutes+" minutos, "+obj.seconds+" segundos y "+obj.miliseconds+" milisegundos para Navidad");

Artículos Relacionados

• Cambiar centro de rotación de un Movieclip en ActionScript 2
• Problemas de carga con Loader y ScrollPane en Flash
• Añadir a un MovieClip un efecto de espejo con Actionscript 2

actionscript

Anotado
muy util para calcular cumpleaños y demas ...
Por: MorphX

Según yo, esto tiene una explicación:

Código :

var sept:Date=new Date (2006,8,1)
//No, no me equivoco, en flash los meses están indexados a 0 por lo que Septiembre es el mes 7
difHoras= Math.floor((sept.getTime()-new Date().getTime())/(1000*60*60))
trace(difHoras);

Por lógica, sé lo que paso:

zah codeando
cerebro, var sept:Date=new Date (2006,8,1) // 8 por que meses en Flash = mes -1
explicando
cerebro, El mes de septiembre, volte a ver código, es 8, en eso recuerda que mes en flash = mes-1 entonces dice 7

Por lo tanto el código esta bien, simplemente en el comentario volvio a restar uno al mes.

Salvo que zah diga lo contrario, eso fué lo que paso.
Por: Dano

Muy buena Dano, y sí fue justo eso, supongo.
Por: Zah