Comunidad de diseño web y desarrollo en internet online

Cómo crear transiciones entre fotogramas en Flash

Hace unos días me preguntaron como crear transiciones entre fotogramas en Flash. Esto es una tarea bastante sencilla de implementar así que aprovecho para explicarla en forma de Tip.

Lo que se pretende conseguir es que al cambiar de fotograma, los elementos del fotograma actual desaparezcan de forma animada antes de saltar al siguiente fotograma. Como se ve en el ejemplo:


Clicka en los botones de colores


Esta sencilla película está estructurada en varios fotogramas con un elemento diferente en cada uno de ellos y una serie de botones que nos hacen saltar de uno a otro.



La idea del ejemplo es que cada fotograma esté contenido en un MovieClip que contenga a su vez la animación de entrada y salida. Y por código haremos que se reproduzcan estas animaciones al cambiar de fotograma.

En el primer fotograma del MovieClip tendremos todo su contenido tal cual nos interese tener en pantalla, y apartir del segundo fotograma haremos la animación de entrada y salida.

Para este ejemplo la animación de entrada y salida será la misma interpolación de movimiento que reproduciremos adelante o hacia atrás según sea el caso.



Para poder referenciar el código colocaremos un Label "on" en el primer frame de la animación, un Label "anim" en los fotogramas internos de la animación, y un Label "out" en el último fotograma de la animación.



Ahora vayamos al código:



Empezaremos por la clase Main.as, que es la clase de la pelicula y donde asignaremos los comportamientos a los botones:

Código :

package {
   import flash.display.MovieClip;
   import flash.events.MouseEvent;
   //
   public class Main extends MovieClip {

      public var currentFrameClip:MovieClip;

      public function Main() {
         this.boton1.addEventListener(MouseEvent.CLICK,gotoFrame);
         this.boton2.addEventListener(MouseEvent.CLICK,gotoFrame);
         this.boton3.addEventListener(MouseEvent.CLICK,gotoFrame);
         this.boton4.addEventListener(MouseEvent.CLICK,gotoFrame);
         this.stop();
      }
      private function gotoFrame(e:MouseEvent):void {
         switch (e.currentTarget) {
            case boton1 :
               currentFrameClip.gotoFrame(1);
               break;
            case boton2 :
               currentFrameClip.gotoFrame(2);
               break;
            case boton3 :
               currentFrameClip.gotoFrame(3);
               break;
            case boton4 :
               currentFrameClip.gotoFrame(4);
               break;
         }
      }
   }
}

Aquí lo único que hacemos es que los botones de la película hagan ejecutar al MovieClip, referenciado desde una variable "currentFrameClip", un método llamado "gotoFrame", que como su nombre indica nos hará saltar al fotograma pasado como parámetro.

Vayamos ahora a la clase que asignaremos a cada uno de los MovieClip de los fotogramas y que es la que hará reproducir la animación y saltar de fotograma:

Código :

package {
   import flash.display.MovieClip;
   import flash.events.Event;
   //
   public class FrameInOut extends MovieClip {

      public var goto:uint;
      
      public function FrameInOut() {
         MovieClip(this.parent).currentFrameClip=this;
         frameIntro();
      }
      public function gotoFrame(frame:uint):void {
         if (frame!=MovieClip(this.parent).currentFrame) {
            goto=frame;
            this.gotoAndStop("on");
            this.addEventListener(Event.ENTER_FRAME,avanzaFrame);
         }
      }
      //-----------------------------------------------------
      private function frameIntro():void {
         this.gotoAndStop("out");
         this.addEventListener(Event.ENTER_FRAME,retrocedeFrame);
      }
      private function retrocedeFrame(e:Event):void {
         if (this.currentLabel=="on") {
            this.removeEventListener(Event.ENTER_FRAME,retrocedeFrame);
         } else {
            this.prevFrame();
         }
      }
      private function avanzaFrame(e:Event):void {
         if (this.currentLabel=="out") {
            this.removeEventListener(Event.ENTER_FRAME,avanzaFrame);
            MovieClip(this.parent).gotoAndStop(goto);
         } else {
            this.nextFrame();
         }
      }
   }
}


Esta clase lo que hace es guardar el valor del fotograma al que debe de saltar. Luego reproduce la animación de salida desplazandose desde el Label "on" al Label "out", y es entonces cuando llama ejecutar el gotoAndStop que hace cambiar de fotograma.

El contructor de la clase también tiene una llamada a una función que hace reproducir la animación de entrada creandose así la transición de un fotograma al otro.

Aquí puedes descargarte el archivo.

UPDATE:


Después de una charla con Eldervaz sobre la conveniencia del uso de enter_frames, decidió hacer una versión de su código para este tip.

Su propuesta consiste en eliminar las funciones de reproducción de la clase dejando ese trabajo a hacer por línea de tiempo desde el .FLA. Aquí muestro la clase resultante:

Código :

package
{
   import flash.display.MovieClip;
   import flash.events.Event;
   //
   public class FrameInOut extends MovieClip
   {
      public var goto:uint;
      //
      public function FrameInOut()
      {
         MovieClip(this.parent).currentFrameClip = this;
         this.gotoAndPlay("out");
      }
      public function gotoFrame(frame:uint):void
      {
         if(frame != MovieClip(this.parent).currentFrame)
         {
            goto = frame;
            this.addFrameScript(19, foo);
            this.gotoAndPlay("anim");
         }
      }
      private function foo():void
      {
         this.addFrameScript(19, null);
         MovieClip(this.parent).gotoAndStop(goto);
      }
   }
}


Y aquí el resto de archivos a descargar.

Hay que puntualizar que siempre existen muchas maneras de conseguir el mismo objetivo y que una no es mejor que otra sino que depende de cuales sean nuestras necesidades. Lo importante de tip es aprender el concepto seguido y saber adaptarlo a nuestro caso.

¿Sabes SQL? ¿No-SQL? Aprende MySQL, PostgreSQL, MongoDB, Redis y más con el Curso Profesional de Bases de Datos que empieza el martes, en vivo.

Publica tu comentario

o puedes...

¿Estás registrado en Cristalab y quieres
publicar tu URL y avatar?

¿No estás registrado aún pero quieres hacerlo antes de publicar tu comentario?

Registrate